src/core.lnk

Idź do dokumentacji tego pliku.

/* panalix 0.06 core linker script. revision 1.3
-17'04'04 forked from 0.05 branch (rev 1.3) */

LS_Phys = 0x100000; /* 1 meg = load (physical) address */
LS_Virt = 0xC0000000; /* 3 gig = virtual address */

SECTIONS
{
   .text LS_Virt : AT(LS_Phys)
    {   code = .; _code = .;
        *(.text*)                /* kernel code at 3 gig */
        *(.rodata*)             /* read-only data */
        . = ALIGN(4096);
        d_code = .; _d_code = .;
       *(.dtext)               /* discardable kernel code */
       . = ALIGN(4096); }





/*    .data : AT( ADDR( .text ) + SIZEOF ( .text ) - LS_Virt + LS_Phys )*/






   .data : AT ( ADDR(.text)+SIZEOF(.text) - LS_Virt + LS_Phys  )
    {
        data = .; _data = .;
        __CTOR_LIST__ = .; LONG((__CTOR_END__ - __CTOR_LIST__) / 4 - 2) *(.ctors)   LONG(0) __CTOR_END__ = .; 
        __DTOR_LIST__ = .; LONG((__DTOR_END__ - __DTOR_LIST__) / 4 - 2) *(.dtors) LONG(0) __DTOR_END__ = .; 

        *(.data)                /* kernel data */
        *(.eh_frame)
        . = ALIGN(4096);
        d_data = .; _d_data = .;
        *(.ddata)               /* discardable kernel data */
        . = ALIGN(4096); }




        .rodata : AT( ADDR( .data ) + SIZEOF ( .data ) - LS_Virt + LS_Phys )
        {       rodata = .; _rodata = .;
                *(.rodata)                              /*readonly data*/
                . = ALIGN(4096); }



        .gnu : AT(  ADDR( .rodata ) + SIZEOF ( .rodata ) - LS_Virt + LS_Phys )
        {       gnu = .; _gnu = .;
                *(.gnu.*)                               /*gnu data*/
                . = ALIGN(4096); }


    .bss : AT( ADDR( .gnu ) + SIZEOF ( .gnu ) - LS_Virt + LS_Phys )
    {   bss = .; _bss = .;
        *(.bss.dontcare)        /* bss' not to be zeroed */
        bss2 = .;
        *(.bss)                 /* kernel BSS */
        *(COMMON)               /* 'common' vars */
        . = ALIGN(4096);
        bssend = .; }


        end = .; _end = .; }


OUTPUT(core.x)

/* initialisation */
STARTUP(src/crt.o)
INPUT(src/init.o)
INPUT(src/memory/paging.o)
/* x86 arch */
INPUT(src/arch/x86/gdt.o)
INPUT(src/arch/x86/interr.o)
INPUT(src/arch/x86/except_c.o)
INPUT(src/arch/x86/irq.o)
INPUT(src/arch/x86/except.o)
INPUT(src/arch/x86/rtc.o)
INPUT(src/arch/x86/context.o)
INPUT(src/arch/x86/sched.o)
INPUT(src/arch/x86/cpuid.o)
INPUT(src/arch/x86/msr.o)
INPUT(src/arch/x86/sysenter.o)
INPUT(src/arch/x86/wp.o)
INPUT(src/arch/x86/pcibios.o)
/* general functionality */
INPUT(src/common/shared.o)
INPUT(src/common/error.o)
INPUT(src/common/io.o)
INPUT(src/common/string.o)
INPUT(src/common/stack.o)
INPUT(src/common/blist.o)
INPUT(src/common/blistsort.o)
INPUT(src/common/qsort.o)
INPUT(src/common/bits.o)
INPUT(src/common/profiler.o)
INPUT(src/common/prng.o)
INPUT(src/mboot.o)
INPUT(src/ata.o)
INPUT(src/fat.o)
/* collection */
INPUT(src/collection/collection.o)
/* net */
INPUT(src/net/3c556.o)
INPUT(src/net/net.o)
INPUT(src/net/ip.o)
INPUT(src/net/tcp.o)
INPUT(src/net/icmp.o)
INPUT(src/net/arp.o)
/* debug */
INPUT(src/sandbox.o)
/* virtual console management */
INPUT(src/tty/teletype.o)
/* memory management */
INPUT(src/memory/memset.o)
INPUT(src/memory/pager.o)
INPUT(src/memory/alloc4k.o)
INPUT(src/memory/align.o)
INPUT(src/memory/heap.o)
INPUT(src/memory/zone.o)
INPUT(src/memory/mmap.o)
INPUT(src/memory/shmem.o)
/* interr process communication */
INPUT(src/ipc/lock.o)
INPUT(src/ipc/msg.o)
INPUT(src/ipc/sem.o)
/* multithreading and multitasking */
INPUT(src/thread/thread.o)
INPUT(src/thread/process.o)
INPUT(src/thread/scheduler.o)
INPUT(src/thread/timer.o)
/* module support */
INPUT(src/module/elf.o)
INPUT(src/module/coresyms.o)
INPUT(src/module/mangle.o)
INPUT(src/module/mods.o)
INPUT(src/module/api1.o)
INPUT(src/module/deamon.o)
/* main function */
INPUT(src/main.o)
/* gcc functions */
INPUT(src/libgcc.a) 

OUTPUT_FORMAT(elf32-i386)
ENTRY(start)

---