src/arch/x86/sched.s

Idź do dokumentacji tego pliku.

/***********************************************************
*PANALIX 0.06, (c) Adrian Panasiuk 2002,3                  *
*adek336[at]o2.pl, panalix.prv.pl                          *
*under GPLv3 license                                       *
*                                                          *
*panalix - small osdev project                             *
************************************************************
*       sched.s, version 1.0                               *
*                                                          *
************************************************************
*                                                          *
*a simple wrapper for the scheduling function, connected   *
*to the PIT                                                *
*                                                          *
*02'05'04- first revision(1.0)                             *
*                                                          *
***********************************************************/

/*----------------------------------------------------------*/
.globl scheduler_wrapper

/* current_thread struct */
.extern current_thread
.extern kernel_tss

.text
/*macros*/

/* issue end of interrupt and return to caller */
.extern eloziom
.macro eoi_iret
/* issue eoi */
        push %eax
        movb $0x20, %al
        outb %al, $0x20
        pop %eax
/* iret */
        iret
.endm

.equ thread_ksp, 0
.equ thread_tsp, 4
.equ thread_isp, 8

.lcomm Temp_DS_Storage, 4
.lcomm Temp_SS_Storage, 4
.lcomm Temp_ESP_Storage, 4
.lcomm Scheduler_First_Run, 4
/* save the current thread's context */
.macro context_save
/* change ds to the good value*/
        pushl %ds
        pushl %ss
        pushl $0x10
        pushl $0x10
        popl %ds
        popl %ss
        popl (Temp_SS_Storage)
        popl (Temp_DS_Storage)
/* check if this is the first run ? */
        cmpl $0, (Scheduler_First_Run)
        je skip_run
/* Temp_ESP_Storage = esp */
        movl %esp, (Temp_ESP_Storage)
/* esp=current_thread->ksp */
        mov (current_thread), %esp
        mov thread_ksp(%esp), %esp
/* push regs */
        pushl (Temp_ESP_Storage)
        pusha
        pushl (Temp_DS_Storage)
        pushl %es
        pushl %fs
        pushl %gs
/* current_thread->ksp=esp */
        movl (current_thread), %eax
        mov %esp, thread_ksp(%eax)
/* current_thread->tsp=Temp_ESP_Storage */
        movl (current_thread), %eax
        movl (Temp_ESP_Storage), %ebx
        movl %ebx, thread_tsp(%eax)
skip_run:
        movl $1, (Scheduler_First_Run)
.endm

/* restore the current thread's context */
.extern pr
.macro context_restore
/* esp = current_thread->ksp */
        mov (current_thread), %esp
        mov thread_ksp(%esp), %esp
/* current_thread->ksp+=0x34 */
        movl (current_thread), %eax
        addl $0x34, thread_ksp(%eax)
/* kernel_tss.esp0=current_thread->tsp */
        movl (current_thread), %eax
        movl thread_isp(%eax), %ecx
        movl $kernel_tss, %eax
        movl %ecx, 4(%eax) 

/* pop all regs. now be careful with the regs */
        popl %gs
        popl %fs
        popl %es
        popl %ds
        popa
/* restore stack */
        popl %esp
.endm

.lcomm Temp_Stack, 0x400
/* find next runnable thread */
.macro scheduler_run
/* setup a temporary stack */
        mov $Temp_Stack, %esp
        pushl $0x10
        popl %es
        pushl $0x10
        popl %fs
        pushl $0x10
        popl %gs
        addl $0x400, %esp       /* end of stack */
        call choose_next_thread
.endm

/* does not return */
scheduler_wrapper:
        context_save
        scheduler_run
/*      incl (0xb8000)  debug */
        context_restore
        eoi_iret

.data

.bss

/***********************************************************
*                                                          *
*panalix 0.06 (c) Adrian Panasiuk 2002,3                   *
*adek336[at]o2.pl, panalix.prv.pl                          *
*                                                          *
***********************************************************/

---